home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS12.ADF / PopCLI / WBC.a < prev    next >
Text File  |  1986-08-05  |  5KB  |  209 lines
  1.     section    text,CODE
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Requirements:
  5.  
  6.     INCLUDE    "exec/types.i"
  7.     INCLUDE "exec/alerts.i"
  8.     INCLUDE "exec/nodes.i"
  9.     INCLUDE "exec/lists.i"
  10.     INCLUDE "exec/ports.i"
  11.     INCLUDE "exec/libraries.i"
  12.     INCLUDE "exec/tasks.i"
  13.     INCLUDE "libraries/dos.i"
  14.     INCLUDE "libraries/dosextens.i"
  15.  
  16. ; some usefull macros:
  17. xlib    macro
  18.     xref    _LVO\1
  19.     endm
  20.  
  21. callsys    macro
  22.     CALLLIB    _LVO\1
  23.     endm
  24.     
  25.  
  26.     xdef    _XCEXIT            * exit(code) is standard way to leave C.
  27.     xdef    _HandlerInterface
  28.  
  29.     xref    _myhandler
  30.     xref    __main            * Name of C program to start with.
  31.     xref    _AbsExecBase
  32.     xref    _FindTask
  33.     xref    _DOSBase
  34.  
  35.     xlib    Alert
  36.     xlib    FindTask
  37.     xlib    Forbid
  38.     xlib    GetMsg
  39.     xlib    OpenLibrary
  40.     xlib    CloseLibrary
  41.     xlib    ReplyMsg
  42.     xlib    Wait
  43.     xlib    WaitPort
  44.     xlib    Open
  45.     xlib    Close
  46.     xlib    CurrentDir
  47.  
  48. start:
  49.     move.l    d0,dosCmdLen
  50.     move.l    a0,dosCmdBuf
  51.     move.l    a7,d0            ; save old stack ptr
  52.     movem.l    d1-d6/a0-a6,-(a7)
  53.     move.l    d0,a5
  54.     move.l    _AbsExecBase,a6
  55.     move.l    a6,_SysBase
  56.     move.l    a7,__StackPtr        * Save stack ptr
  57.  
  58. ;------ get the address of our task
  59.     suba.l    a1,a1
  60.     callsys    FindTask
  61.     move.l    d0,a4
  62.  
  63. ;------ are we running as a son of Workbench?
  64.     move.l    pr_CurrentDir(A4),_curdir
  65.     tst.l    pr_CLI(A4)
  66.     beq    exit2
  67.  
  68. ;=======================================================================
  69. ;====== CLI Startup Code ===============================================
  70. ;=======================================================================
  71.  
  72. fromCLI:
  73.     move.l    a5,D0        ; get top of stack
  74.     sub.l    4(a5),D0    ; compute bottom 
  75.     move.l    D0,__base    ; save for stack checking
  76. ;------    attempt to open DOS library:
  77.     lea    DOSName,A1
  78.     moveq.l    #0,D0
  79.     callsys OpenLibrary
  80.     move.l    D0,_DOSBase
  81.     beq    noDOS
  82.  
  83. ;------ find command name:
  84.     move.l    #start,a0
  85.     clr.l    -(sp)
  86.     jsr    _FindTask
  87.     addq.l    #4,sp
  88.     move.l    d0,a0
  89.     move.l    pr_CLI(a0),a0
  90.     add.l   a0,a0        ; bcpl pointer conversion
  91.     add.l   a0,a0
  92.     move.l    cli_CommandName(a0),a1
  93.     add.l   a1,a1        ; bcpl pointer conversion
  94.     add.l   a1,a1
  95.  
  96. ;------    collect parameters:
  97.     move.l    dosCmdLen,d0        ; get command line length
  98.     move.l    a1,__ProgramName
  99.     addq.l    #1,d0            ; allow for space after command    
  100.  
  101.     clr.w    -(A7)            ; set null terminator for command line
  102.     addq.l    #1,D0            ; force to even number of bytes
  103.     andi.w    #$fffe,D0        ;(round up)
  104.     sub.l    D0,A7            ; make room on stack for command line
  105.     subq.l    #2,D0
  106.     clr.w    0(A7,D0)
  107.  
  108. ;------ copy command line onto stack
  109.     move.l    dosCmdLen,d0        ; get command line length
  110.     move.l    dosCmdBuf,a0
  111.     move.l    d0,d2
  112.     subq.l    #1,d0
  113.  
  114. copy_line:
  115.     move.b    0(A0,D0.W),0(A7,D2.W)    ; copy command line to stack
  116.     subq.l    #1,d2
  117.     dbf    d0,copy_line
  118.     move.b    #' ',0(a7,d2.w)        ; add space between command and parms
  119.     subq.l    #1,d2
  120.  
  121.     move.l    A7,A1
  122.     move.l    A1,-(A7)        ; push command line address
  123.     jsr    __main                * call C entrypoint
  124.     moveq.l    #0,d0            ; set successful status
  125.     bra.l    exit2
  126.  
  127. _XCEXIT:
  128.     move.l    4(SP),d0    ; extract return code
  129. exit2:
  130.     move.l    d0,-(a7)
  131.     move.l    _SysBase,a6
  132.     move.l    _DOSBase,a1
  133.     callsys    CloseLibrary        ; close Dos library
  134.  
  135. ;------ this rts sends us back to DOS:
  136. exitToDOS:
  137.     MOVE.L    (A7)+,D0
  138.     movea.l  __StackPtr,SP        * restore stack ptr
  139.     movem.l    (a7)+,d1-d6/a0-a6
  140.     rts                * and exit
  141.  
  142. ;-----------------------------------------------------------------------
  143. noDOS:
  144.         ALERT    (AG_OpenLib!AO_DOSLib)
  145.         moveq.l    #100,d0
  146.         bra    exit2
  147.  
  148. *************************************************************************
  149. *   HandlerInterface()
  150. *
  151. *   This code is needed to convert the calling sequence performed by
  152. *   the input.task for the input stream management into something
  153. *   that a C program can understand.
  154. *
  155. *   This routine expects a pointer to an InputEvent in A0, a pointer
  156. *   to a data area in A1.  These values are transferred to the stack
  157. *   in the order that a C program would need to find them.  Since the
  158. *   actual handler is written in C, this works out fine. 
  159. *
  160. *   Author: Rob Peck, 12/1/85
  161. *
  162.  
  163. _HandlerInterface:
  164.     movem.L    A0/A1,-(A7)
  165.     jsr    _myhandler
  166.     addq.L    #8,A7
  167.     rts
  168.  
  169.     section    data,DATA
  170. ;
  171.     XDEF    _NULL,_SysBase,_LoadAddress,_console_dev,_WBenchMsg
  172.     XDEF    _curdir,__mbase,__mnext,__msize,__tsize
  173.     XDEF    __oserr,__OSERR,__FPERR,__SIGFPE,__ONERR,__ONEXIT,__ONBREAK
  174.     XDEF    __SIGINT
  175.     XDEF    _errno,_stdin,_stdout,_stderr
  176.     XDEF    __ProgramName,__StackPtr,__base
  177. ;
  178. _errno        dc.l    0
  179. _stdin        dc.l    0
  180. _stdout        dc.l    0
  181. _stderr        dc.l    0
  182. _NULL        dc.l    0        ;
  183. __base        dc.l    0        ; base of stack
  184. __mbase        dc.l    0        ; base of memory pool
  185. __mnext        dc.l    0        ; next available memory location
  186. __msize        dc.l    0        ; size of memory pool
  187. __tsize        dc.l    0        ; total size?
  188. __oserr        equ    *
  189. __OSERR        dc.l    0
  190. __FPERR        dc.l    0
  191. __SIGFPE    dc.l    0
  192. __SIGINT    dc.l    0
  193. __ONERR        dc.l    0
  194. __ONEXIT    dc.l    0
  195. __ONBREAK    dc.l    0
  196. _curdir        dc.l    0
  197. _console_dev    dc.l    0
  198. _SysBase    dc.l    0
  199. _LoadAddress    dc.l    0            ; program load address
  200. _WBenchMsg    dc.l    0
  201. __StackPtr    dc.l    0
  202. dosCmdLen    dc.l    0
  203. dosCmdBuf    dc.l    0
  204. stdin        dc.l    0
  205. __ProgramName    dc.l    0
  206. DOSName     DOSNAME
  207.  
  208.     END
  209.